https://www.opennet.ru/opennews/art.shtml?num=61301Подправил рецепт и скомпилил под roll2402
pkgname=ladybird-git
pkgver=r61764.baf7a2dee7
pkgrel=1
pkgdesc='Web browser built from scratch using the SerenityOS LibWeb engine'
arch=(x86_64)
url='https://github.com/LadybirdWebBrowser/ladybird'
license=(BSD)
depends=(brotli less libgl python qt6-base qt6-multimedia qt6-svg qt6-wayland)
conflicts=(ladybird)
provides=(ladybird)
makedepends=(cmake git ninja qt6-tools unzip)
options=('!lto' '!debug')
source=(
"git+$url"
"ladybird.desktop"
)
sha256sums=(
'SKIP'
'SKIP'
)
pkgver() {
cd ladybird
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}"
cmake \
-B build/ladybird \
-S ladybird/Ladybird \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-GNinja \
-Wno-dev
ninja -C build/ladybird
}
package() {
cd "${srcdir}"
DESTDIR="${pkgdir}" ninja -C build/ladybird install
install -Dm644 "ladybird.desktop" "${pkgdir}/usr/share/applications/ladybird.desktop"
install -Dm644 "ladybird/Base/res/icons/32x32/app-browser.png" "${pkgdir}/usr/share/pixmaps/ladybird.png"
install -Dm644 ladybird/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
19M ladybird-git-r61764.baf7a2dee7-1-x86_64.pkg.tar.zst
размер радует. Остальное - нет
ya.ru - падает
youtube - виснет и тормозит
Наш форум тормозит, но работает
Может со временем что-то и получится...
Кому интересно - пишите - выложу, пока не стер